{

  description = "web-overview for dhcp-leases from dnsmasq";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.05";

  outputs = inputs: let
    forAllSystems = function:
      inputs.nixpkgs.lib.genAttrs [
        "x86_64-linux"
        "aarch64-linux"
        "aarch64-darwin"
      ] (system: function (import inputs.nixpkgs {
        system   = system;
        overlays = [ inputs.self.overlays.default ];
      }));

  in {

    packages = forAllSystems (pkgs: {
      default                = pkgs.dnsmasq-lease-overview;
      dnsmasq-lease-overview = pkgs.dnsmasq-lease-overview;
    });

    apps = forAllSystems (pkgs: {
      default.type    = "app";
      default.program = "${pkgs.dnsmasq-lease-overview}/bin/overview";
    });

    overlays.default = final: prev: {
      dnsmasq-lease-overview = let
        nim-mustache = final.fetchFromGitHub {
          owner  = "soasme";
          repo   = "nim-mustache";
          rev    = "v0.4.3";
          sha256 = "sha256-rrmKSb422YALxg0nV8rjTNgLecJAM8jvg8tnbvSa9SY";
        };

      in final.buildNimPackage {
        name = "dnsmasq-lease-overview";
        src  = inputs.self;

        nimRelease = true;
        nimFlags   = [
          "--showAllMismatches:on"
          "--path:${nim-mustache}/src"
        ];
      };
    };

  };

}